mirror of
git://code.qt.io/qt/qt5.git
synced 2026-02-01 19:36:04 +08:00
435a7c7739
Still useful to use init-repository because of all the other logic, such as repository urls. More general than --no-webkit, although it is still a valid convenience as the most common case. Also makes qt.pro check for existence of modules, since it is no longer certain that you'll have everything but webkit. Change-Id: Iaaaa30e24e0a793218e2e307bdde56067760c513 Reviewed-on: http://codereview.qt.nokia.com/1258 Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com> Reviewed-by: Rohan McGovern <rohan.mcgovern@nokia.com>
119 lines
4.7 KiB
INI
119 lines
4.7 KiB
INI
TEMPLATE = subdirs
|
|
|
|
module_qtbase.subdir = $$IN_PWD/qtbase
|
|
module_qtbase.target = module-qtbase
|
|
|
|
module_qtsvg.subdir = $$IN_PWD/qtsvg
|
|
module_qtsvg.target = module-qtsvg
|
|
module_qtsvg.depends = module_qtbase
|
|
|
|
module_qtphonon.subdir = $$IN_PWD/qtphonon
|
|
module_qtphonon.target = module-qtphonon
|
|
module_qtphonon.depends = module_qtbase
|
|
|
|
module_qtmultimedia.subdir = $$IN_PWD/qtmultimedia
|
|
module_qtmultimedia.target = module-qtmultimedia
|
|
module_qtmultimedia.depends = module_qtbase
|
|
|
|
module_qtxmlpatterns.subdir = $$IN_PWD/qtxmlpatterns
|
|
module_qtxmlpatterns.target = module-qtxmlpatterns
|
|
module_qtxmlpatterns.depends = module_qtbase
|
|
|
|
module_qtscript.subdir = $$IN_PWD/qtscript
|
|
module_qtscript.target = module-qtscript
|
|
module_qtscript.depends = module_qtbase
|
|
|
|
module_qtdeclarative.subdir = $$IN_PWD/qtdeclarative
|
|
module_qtdeclarative.target = module-qtdeclarative
|
|
module_qtdeclarative.depends = module_qtbase module_qtscript module_qtsvg module_qtxmlpatterns
|
|
|
|
module_qtwebkit.file = qtwebkit.pri
|
|
module_qtwebkit.makefile = Makefile.qtwebkit
|
|
module_qtwebkit.depends = module_qtbase module_qtscript module_qtdeclarative module_qtphonon
|
|
# The qtwebkit subdir does not follow the "module-*" scheme, so make our own target that does.
|
|
module_qtwebkit_target.target = module-qtwebkit
|
|
module_qtwebkit_target.commands =
|
|
module_qtwebkit_target.depends = sub-qtwebkit-pri
|
|
QMAKE_EXTRA_TARGETS += module_qtwebkit_target
|
|
|
|
module_qtwebkit_examples_and_demos.subdir = $$IN_PWD/qtwebkit-examples-and-demos
|
|
module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
|
|
module_qtwebkit_examples_and_demos.depends = module_qtwebkit
|
|
|
|
module_qttools.subdir = $$IN_PWD/qttools
|
|
module_qttools.target = module-qttools
|
|
module_qttools.depends = module_qtbase module_qtscript module_qtdeclarative
|
|
win32:module_qttools.depends += module_qtactiveqt
|
|
|
|
module_qttranslations.subdir = $$IN_PWD/qttranslations
|
|
module_qttranslations.target = module-qttranslations
|
|
module_qttranslations.depends = module_qttools
|
|
|
|
module_qtdoc.subdir = $$IN_PWD/qtdoc
|
|
module_qtdoc.target = module-qtdoc
|
|
module_qtdoc.depends = module_qtdeclarative module_qttools #for the demos and QtHelp
|
|
|
|
module_qtactiveqt.subdir = $$IN_PWD/qtactiveqt
|
|
module_qtactiveqt.target = module-qtactiveqt
|
|
module_qtactiveqt.depends = module_qtbase
|
|
|
|
module_qlalr.subdir = $$IN_PWD/qlalr
|
|
module_qlalr.target = module-qlalr
|
|
module_qlalr.depends = module_qtbase
|
|
|
|
module_qtqa.subdir = $$IN_PWD/qtqa
|
|
module_qtqa.target = module-qtqa
|
|
module_qtqa.depends = module_qtbase
|
|
|
|
module_qtlocation.subdir = $$IN_PWD/qtlocation
|
|
module_qtlocation.target = module-qtlocation
|
|
module_qtlocation.depends = module_qtbase module_qtdeclarative
|
|
|
|
module_qtsensors.subdir = $$IN_PWD/qtsensors
|
|
module_qtsensors.target = module-qtsensors
|
|
module_qtsensors.depends = module_qtbase module_qtdeclarative
|
|
|
|
module_qtsystems.subdir = $$IN_PWD/qtsystems
|
|
module_qtsystems.target = module-qtsystems
|
|
module_qtsystems.depends = module_qtbase module_qtdeclarative
|
|
|
|
module_qtmultimediakit.subdir = $$IN_PWD/qtmultimediakit
|
|
module_qtmultimediakit.target = module-qtmultimediakit
|
|
module_qtmultimediakit.depends = module_qtbase module_qtdeclarative
|
|
|
|
module_qtfeedback.subdir = $$IN_PWD/qtfeedback
|
|
module_qtfeedback.target = module-qtfeedback
|
|
module_qtfeedback.depends = module_qtbase module_qtdeclarative
|
|
# not yet enabled by default
|
|
module_qtfeedback.CONFIG = no_default_target no_default_install
|
|
|
|
# only qtbase is required to exist. The others may not - but it is the
|
|
# users responsibility to ensure that all needed dependencies exist, or
|
|
# it may not build.
|
|
|
|
SUBDIRS = module_qtbase
|
|
|
|
exists(qtsvg/qtsvg.pro): SUBDIRS += module_qtsvg
|
|
exists(qtphonon/qtphonon.pro): SUBDIRS += module_qtphonon
|
|
exists(qtxmlpatterns/qtxmlpatterns.pro): SUBDIRS += module_qtxmlpatterns
|
|
exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
|
|
exists(qtdeclarative/qtdeclarative.pro): SUBDIRS += module_qtdeclarative
|
|
exists(qtmultimedia/qtmultimedia.pro): SUBDIRS += module_qtmultimedia
|
|
exists(qttools/qttools.pro): SUBDIRS += module_qttools
|
|
exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
|
|
exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
|
|
exists(qlalr/qlalr.pro): SUBDIRS += module_qlalr
|
|
exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa
|
|
exists(qtlocation/qtlocation.pro): SUBDIRS += module_qtlocation
|
|
exists(qtactiveqt/qtactiveqt.pro): SUBDIRS += module_qtactiveqt
|
|
exists(qtsensors/qtsensors.pro): SUBDIRS += module_qtsensors
|
|
exists(qtsystems/qtsystems.pro): SUBDIRS += module_qtsystems
|
|
exists(qtmultimediakit/qtmultimediakit.pro): SUBDIRS += module_qtmultimediakit
|
|
exists(qtfeedback/qtfeedback.pro): SUBDIRS += module_qtfeedback
|
|
|
|
exists(qtwebkit/Tools/Scripts/build-webkit) {
|
|
SUBDIRS += module_qtwebkit \
|
|
module_qtwebkit_examples_and_demos
|
|
module_qttools.depends += module_qtwebkit
|
|
}
|